contract.idl

Go to the documentation of this file.

// OSB library ********************************************* -*- IDL -*-
/*
  AUTHOR(S): Darryl Kang (dk)

  RCS information
   $Name: OSB_060808 $
   $Revision: 1.37.2.1 $

  License
   OSB rating and billing library for communication networks
   Copyright (C) 2004, 2005, 2006  OSB systems

   This file may be distributed and/or modify under the terms of the
   GNU General Public License (GPL) as published by the Free Software
   Foundation which is provided in the file LICENSE.GPL included in the
   packaging of this file.

   The file is distributed in the hope that it will be useful, but WITHOUT
   ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
   FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
   for more details.

   Holders of a OSB Commercial License may use this file under the terms
   and conditions of this commercial license.
 */
#ifndef CONTRACT_IDL
#define CONTRACT_IDL
// *********************************************************************
#include "corba_utility.idl"
#include "persproduct.idl"
#include "product.idl"
#include "balancesheet.idl"

module corba {
  module cadmin {
    module contract {


      enum BillCycleType {
          btUnknown,           
          btIntervalBillCycle, 
          btDateBillCycle      
      };

      struct BillCycle {
          BillCycleId id;

          common::Utf8String name;

          common::Utf8String desc;
      };

      typedef sequence<BillCycle> BillCycleSeq;

      enum AccountingType {
          atUnknown,

          atCustomer,

          atSupplier
      };

      enum StatementType {
          stUnknown,

          stInvoice,

          stReconciliation
      };

      struct InvoiceInfo {
          BsPageId bpId;

          common::Utf8String invoiceNumber;

          ContractId conId;

          StatementType type;

          common::Date billDate;

          common::Date startDate;

          common::Date endDate;

          common::Money amt;

          common::Utf8String hostName;

          common::Utf8String fileInfo;
      };

      typedef sequence<InvoiceInfo> InvoiceInfoSeq;

      interface ContractWriter {
          readonly attribute ContractId id;
          readonly attribute cadmin::AssociateId owner;

          readonly attribute common::TaxKeyId tkId;

          readonly attribute AccountingType acctType;

          readonly attribute BillCycleId bcId;

          readonly attribute common::DateTime createdDate;

          readonly attribute Status effStatus;

          readonly attribute Status prefStatus;

          readonly attribute common::DateTime effStatusDate;

          readonly attribute common::DateTime prefStatusDate;

          readonly attribute common::Money creditLimit;

          StatusValue requestedStatus(
              in common::DateTime ts
          ) raises (common::OsbCorbaException);

          StatusHistory statusHistory(
              in common::DateTime from,
              in common::DateTime to,
              in boolean          noWait
          ) raises (common::OsbCorbaException);

          common::Utf8String getStatement(
              in common::Utf8String fileInfo
          ) raises (common::OsbCorbaException);

          InvoiceInfoSeq getStatements(
              in StatementType type,
              in boolean noWait
          ) raises (common::OsbCorbaException);

          BalanceSheetWriter getBalanceSheet(
              in boolean noWait
          ) raises (common::OsbCorbaException);

          cadmin::persprod::PersProductWriter getPersProduct(
              in cadmin::PersProdId id,
              in boolean            noWait
          ) raises (common::OsbCorbaException);

          cadmin::persprod::PersProdSeq getPersProducts(
              in boolean noWait
          ) raises (common::OsbCorbaException);

          boolean setTaxKey(in common::TaxKeyId tkId);

          boolean setBillCycle(in BillCycleId bcId);

          boolean setCreditLimit(in common::Money credit);

          cadmin::persprod::PersProductWriter addPersProduct(
              in pcat::pd::ProductId id,
              in cadmin::AssociateId userId,
              in boolean             noWait
          ) raises (common::OsbCorbaException);

          boolean removePersProduct(
              in cadmin::PersProdId id,
              in boolean            noWait
          ) raises (common::OsbCorbaException);

          cadmin::ContractId create(
              in cadmin::AssociateId owner,
              in boolean             noWait
          ) raises (common::OsbCorbaException);

          boolean commitChanges(
              in boolean noWait
          ) raises (common::OsbCorbaException);



          boolean changeStatus(
              inout StatusRequest       status,
              in    boolean             noWait,
              out   common::CfgErrorSeq errors
          ) raises (common::OsbCorbaException);
      };                                // interface ContractWriter
    };                                  // module contract
  };                                    // module cadmin
};
#endif                                  // #ifndef CONTRACT_IDL

---